Siehe auch: | Stunden zwischen 2 Zeiten | 

Autor: Beate Schmitz  --- Aus Excel Standard - Gruppe: Häufige Fragen

Negative Zeiten

Autor: Beate Schmitz - Erstellt: 2004-10      - Letzte Revision: ?

Der so genannte Date-Bug in Microsoft Excel: Gartenzaunphänomen bei "negativen-Zeiten"


Das Problem:
Es gibt nunmal keine negativen Zeiten sondern lediglich negative Werte und Excel rechnet absolut richtig mit ihnen, selbst wenn es kein Format für ihre Darstellung gibt, daher der 'Gartenzaun'...


Ein Beispiel (in Zelle E4 werden 10 Stunden dazugezählt):
 
 ABCDEFG
1       
2 IststundenSollstundenDifferenzMan kann aber damit weiterrechnenGetürkte
Differenz
 
3 hh:mmhh:mmhh:mmhh:mmhh:mm 
4 02:4506:30########06:1503:45 
5       
Formeln der Tabelle
D4 : =B4-C4
E4 : =D4+10/24
F4 : =ABS(B4-C4)
 




Ein scheinbarer aber unguter Ausweg, um dem Gartenzaunphänomen zu entkommen:
  • Man kann unter Extras/Optionen/Berechnen das Feld 1904-Datumswerte anklicken.
  • Dann Eingabe negative Zeiten =-"5:30"
  • Format benutzerdefiniert: hh:mm
  • Wenn man die 1904-Option verwendet, springen alle Datumswerte in der Tabelle um 4 Jahre und einen Tag nach vorne, was sich beim Rechnen mit Daten negativ auswirkt!
  • So wird z.B. aus: 02.09.2000 der 03.09.2004



Und nun ein paar Möglichkeiten, wie man den "Gartenzaun" ohne die 1904-Option umgehen kann:
 
 ABCDEFGH
1        
2 BeginnEndeIstSollDifferenz DezimalDifferenz hh:mm 
3 hh:mmhh:mmhh:mmhh:mmDezimal
2 Stellig
hh:mm 
4 07:0015:3008:3008:00-0,5000:30 
5 07:0014:4507:4508:000,25-00:15 
6 07:0017:0010:0008:00-2,0002:00 
7 08:0014:0006:0008:002,00-02:00 
8 Voraussetzung: Beginn und Ende liegen am gleichen Tag
Beginn kleiner Ende
 
9  
10        
Formeln der Tabelle
D4 : =C4-B4
F4 : =(E4-D4)*24
G4 : =TEXT(ABS(E4-D4);WENN(D4<E4;"-";) &"hh:mm")
D5 : =C5-B5
F5 : =(E5-D5)*24
G5 : =TEXT(ABS(E5-D5);WENN(D5<E5;"-";) &"hh:mm")
D6 : =C6-B6
F6 : =(E6-D6)*24
G6 : =TEXT(ABS(E6-D6);WENN(D6<E6;"-";) &"hh:mm")
D7 : =C7-B7
F7 : =(E7-D7)*24
G7 : =TEXT(ABS(E7-D7);WENN(D7<E7;"-";) &"hh:mm")
 

 
 ABCDEFGH
1        
2 Hier werden die Zeiten zur Weiterberechnung ins Dezimalsystem konvertiert: 
3 Format:IstSollDifferenz
Dezimal
Zugangneuer Saldo
Dezimal
 
4 hh:mm08:1512:30 05:00  
5 Zahl mit 2 Dezimal-stellen8,2512,50-4,255,000,75 
6        
Formeln der Tabelle
C5 : =C4*24
D5 : =D4*24
E5 : =C5-D5
F5 : =F4*24
G5 : =F5+E5
 




Mit negativen Uhrzeiten weiterrechnen: (hier am Beispiel Summenbildung)

 ABCDEFG
1       
2 IstSollDifferenz hh:mmSummen-möglichkeiten:Bemerkung: 
3 hh:mmhh:mmhh:mm   
4 08:3014:00-05:30   
5 07:4508:00-00:15   
6 10:0008:0002:00   
7 06:0008:00-02:00   
8    -05:45:00Am einfachsten wieder beide Zeit - Spalten gegeneinander vergleichen: 
9    -05:45:00Oder nach einem Formelvorschlag von Christian Hapke über die Spalte 
10    -05:45:00Ist das ganze mit hh:mm formatiert geht auch 
11       

Formeln der Tabelle
ZelleFormel
D4=TEXT(ABS(C4-B4);WENN(B4<C4;"-";) &"hh:mm")
D5=TEXT(ABS(C5-B5);WENN(B5<C5;"-";) &"hh:mm")
D6=TEXT(ABS(C6-B6);WENN(B6<C6;"-";) &"hh:mm")
D7=TEXT(ABS(C7-B7);WENN(B7<C7;"-";) &"hh:mm")
E8=TEXT(ABS(SUMME(C4:C7)-SUMME(B4:B7));WENN(SUMME(B4:B7)<SUMME(C4:C7);"-";) &"hh:mm:ss")
E9{=TEXT(ABS(SUMME(WENN(LINKS(D4:D7)="-";TEIL(D4:D7;2;99)*-1;D4:D7*1)));WENN(SUMME(WENN(LINKS(D4:D7)="-";TEIL(D4:D7;2;99)*-1;D4:D7*1))<0;"-";)&"[hh]:mm:ss")}
E10{=TEXT(ABS(SUMME((-1+2*(LINKS(D4:D7)<>"-"))*(RECHTS(0&D4:D7;5))));WENN(SUMME((-1+2*(LINKS(D4:D7)<>"-"))*(RECHTS(0&D4:D7;5)))<0;"-";)&"[hh]:mm:ss")}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!


Weitere Artikel der Gruppe: Häufige Fragen Aus Excel Standard
Nach oben
ToDo
Google Werbung