Autor: Peter Haserodt  --- Aus Excel VBA - Gruppe: Verschiedenes

Zugriff auf die Zwischenablage (Clipboard)

Autor: Peter Haserodt - Erstellt: --      - Letzte Revision: --
Dass man aus VBA auf die Zwischenablage (Clipboard) zugreifen kann, ist relativ unbekannt.
Dabei kann man dies mit dem DataObject zumindest für Texte relativ leicht lösen.

Sie benötigen einen Verweis auf die
Microsoft Forms 2.0 Objektlibrary
(Sollte Sie diese nicht so einfach finden, einfach eine Userform einfügen und dann wieder entfernen)


Ansonsten sollten die Beispiele selbsterklärend sein.



' **************************************************************
'  Modul:  mdlCopy  Typ = Allgemeines Modul
' **************************************************************

Option Explicit
' ************************************************************
' Benötigt einen Verweis auf die Microsoft Forms 2.0 Objektlibrary
' Peter Haserodt 2004
' ************************************************************
	
Public Sub TesteEs()
	SchreibeTextInDieZwischenablage
	MsgBox HoleTextVonZwischenablage
	RausMitZwischenAblage
	MsgBox HoleTextVonZwischenablage
End Sub
	
Public Sub SchreibeTextInDieZwischenablage()
	Dim oData As New DataObject
	Dim sText As String
	sText = "Hallo Leute" & vbCrLf & "Neues von Online Excel"
	With oData
		.SetText sText
		.PutInClipboard
	End With
End Sub
	
Public Function HoleTextVonZwischenablage() As String
	Dim oData As New DataObject
	On Error Resume Next ' Brutal um falsche Formate abzuwürgen, gibt dann einen Leerstring
	oData.GetFromClipboard
	HoleTextVonZwischenablage = oData.GetText
End Function
	
Public Sub RausMitZwischenAblage()
	Dim oData As New DataObject
	oData.SetText ""
	oData.PutInClipboard
End Sub
 Peter Haserodt
  • Formelhilfe
  • Makroentwicklung
  • VBA-Programmierung
  • + + + + + + + + +

Weitere Artikel der Gruppe: Verschiedenes Aus Excel VBA
Nach oben