Autor: Peter Haserodt  --- Aus Excel VBA - Gruppe: Häufige Fragen

Abbrechen in Userform

Autor: Peter Haserodt - Erstellt: --      - Letzte Revision: --
Einen Code Abbrechen / Unterbrechen

Immer wieder mal gefragt und da ein Beispiel mehr als tausend Worte sagt:
(Beachten Sie die Benamsung der Steuerelemente)



' **************************************************************
'  Modul:  UserForm1  Typ = Userform
' **************************************************************

Option Explicit
'Peter Haserodt
'************************************************
' Benötigte Steuerelemente (Art:Name:Beschriftung)
'Label : lbllnfo
'Commandbutton: cmdCancel : Abbrechen
'Commandbutton: cmdStart : Start
'*************************************************
Dim bAbbruch As Boolean
 
Private Sub cmdCancel_Click()
 bAbbruch = True
End Sub
 
Private Sub cmdStart_Click()
 bAbbruch = False
 cmdCancel.Enabled = True
 cmdStart.Enabled = False
 MachWas
End Sub
 
Private Sub UserForm_Initialize()
 cmdCancel.Enabled = False
 cmdCancel.Cancel = True
End Sub
 
Private Sub MachWas()
 Dim i As Long
 For i = 1 To 1000000
  DoEvents
  If bAbbruch Then
   bAbbruch = False
   If MsgBox("Wirklich Abbrechen", vbYesNo + vbQuestion) = vbYes Then
    lblInfo.Caption = "Abgebrochen"
    cmdCancel.Enabled = False
    cmdStart.Enabled = True
    Exit Sub
   End If
  End If
  lblInfo.Caption = i
 Next i
 lblInfo.Caption = "bin Fertig"
 cmdCancel.Enabled = False
 cmdStart.Enabled = True
End Sub

Weitere Artikel der Gruppe: Häufige Fragen Aus Excel VBA
Nach oben