Autor: Peter Haserodt  --- Aus Excel Standard - Gruppe: Tutorials

UND * ODER +

Autor: Peter Haserodt - Erstellt: ?      - Letzte Revision: ?
Und * Stern Oder + Plus - was soll denn dieser Stuss
(um Gottes Willen, jetzt fängt der auch noch an zu reimen)

Selbst für den schon etwas Erfahreneren ist es manchmal nicht nachzuvollziehen, wenn solche Dinge in Formeln auftauchen:
 
 ABCDE
1     
2 5 Alle Größer 4 
3 6 Mindestens einer >4 
4 7   
5     
Formeln der Tabelle
D2 : =WENN((B2>4)*(B3>4)*(B4>4);"Alle Größer 4";"Mindesten einer <=4")
D3 : =WENN((B2>4)+(B3>4)+(B4>4);"Mindestens einer >4";"Alle <=4")
 

Tatsächlich ist dies nur eine andere Schreibweise für:
 
 ABCDE
1     
2 5 Alle Größer 4 
3 6 Mindestens einer >4 
4 7   
5     
Formeln der Tabelle
D2 : =WENN(UND(B2>4;B3>4;B4>4);"Alle Größer 4";"Mindesten einer <=4")
D3 : =WENN(ODER(B2>4;B3>4;B4>4);"Mindestens einer >4";"Alle <=4")
 

Ich will hier nicht auf Anwendungsbeispiele eingehen, sondern nur die Logik dahinter erklären.

Auswertung von Vergleichen in Excel

Wenn ich in eine Zelle schreibe : =3>2 so erhalte ich als Ausgabe WAHR.
Wenn ich in eine Zelle schreibe : =3<2 so erhalte ich als Ausgabe FALSCH.

Dies sind Konstanten von Excel. Hinter diesen Konstanten steckt ein Wert, nämlich 1 für WAHR und 0 für FALSCH.
Sie können dieses gerne testen:
 
 ABCD
1    
2 WAHR1 
3 FALSCH0 
4    
Formeln der Tabelle
B2 : =3>2
C2 : =B2*1
B3 : =3<2
C3 : =B3*1
 

Somit ist eines schon mal klar: aus Vergleichen erhalte ich als Ergebnis WAHR oder FALSCH, respektive 0 oder 1 wenn ich es noch "rechnerisch" behandele.

Jetzt kommt der große Trugschluss!!!
Wenn etwas wahr ist, ist es immer 1, wenn etwas falsch ist, ist es immer 0.

Dies ist der größte Irrtum im Umgang mit diesen Ja/Nein Geschichten.
Die Konstanten WAHR/FALSCH sind nur und ausschließlich Rückgaben aus Vergleichen, sie haben mit dem Vergleich ansich nichts zu tun!
Und jetzt kommt das Hääääääääh?
 
 B
2Gut
3Gut
4Gut
5Schlecht
Formeln der Tabelle
B2 : =WENN(44,5;"Gut";"Schlecht")
B3 : =WENN(3;"Gut";"Schlecht")
B4 : =WENN(-1;"Gut";"Schlecht")
B5 : =WENN(0;"Gut";"Schlecht")
 

Sie sehen, nur bei 0 wird der Falschteil der Wennformel ausgeführt.

Man muss sehr genau zwischen der Auswertung einer Bedingung unterscheiden und wie Excel Werte die als Bedingungen dargestellt werden behandelt.

Aus einem Vergleich erhalte ich immer ein Wahr oder Falsch aber aus einem "Wert" immer Wahr, wenn es nicht Falsch ist , was bedeutet: jeder Wert wird von Excel als Wahr behandelt, der <> 0 ist (sofern es ein Wert ist).

Der Große Unterschied ist also: Betrachte ich einen Vergleich oder ein Ergebnis!

 
 ABCD
1    
2 333WAHR
3 144WAHR
4 20FALSCH
5 333WAHR
Formeln der Tabelle
C2 : =WENN(B2>2;33;44)
D2 : =WENN(WENN(B2>2;33;44);WAHR;FALSCH)
C3 : =WENN(B3>2;33;44)
D3 : =WENN(WENN(B3>2;33;44);WAHR;FALSCH)
C4 : =WENN(B4>2;33;0)
D4 : =WENN(WENN(B4>2;33;0);WAHR;FALSCH)
C5 : =WENN(B5>2;33;0)
D5 : =WENN(WENN(B5>2;33;0);WAHR;FALSCH)
 

Versuchen Sie dies nachzuvollziehen, was hier passiert bevor Sie weiterlesen.

Und nun endlich die Auflösung zu unseren * und +

A) Das Und

Bekanntlich ist eine Untersuchung auf Undwerten nur dann WAHR, wenn alle Undbedingungen erfüllt sind.
Deswegen kann man das Ergebnis der einzelnen Vergleiche miteinander multiplizieren und das Produkt dann abprüfen:

Nehmen wir einen einfachen Konstrukt:

(b2>4) * (b3>4)

Beide Vergleiche liefern einen WAHR oder FALSCH zurück, respektive eine 1 oder 0.
Wenn ich nun das Gesamtergebniss auf seinen Wahrheitsgehalt überprüfe, wird mit nur dann WAHR zurückgegeben, wenn beide Bedingungen zutreffen, da sonst in der Multiplikation mindestens eine 0 auftaucht und somit das Produkt immer 0 wird!

Tatsächlich ist dies noch am einfachsten zu Verstehen, da immer 0 oder 1 dabei herauskommt, egal wieviele Vergleiche ich habe, etwas anders sieht es beim ODER aus:

B) Das ODER

Auch hier wird beim einfachen Ausdruck :

(b2>4) + (b3<4)

dies nun schnell einleuchten, denn Oder besagt:
Wenn eine der Bedingungen zutrifft, ist die Gesamtaussage Wahr!

D.h. Nur wenn alle Bedingungen FALSCH sind (0) ergibt die Summe wieder 0 und somit wird das Ergebnis von Excel als FALSCH bewertet (FALSCH im Sinne der Logik).

Was ist aber wenn beide zutreffen, dann erhalte ich doch 2 als Ergebnis???
Und hier ist der Unterschied ganz klar zu sehen. Hier wertet Excel ja nur einen Wert aus und wie oben beschrieben: Alles was nicht 0 ist, wird als WAHR behandelt.

Zum Abschluss:

Wann und wo Sie diese Schreibweise einsetzen, bleibt Ihnen überlassen, gerade in Matrixformeln wird sie häufig genutzt.

Ich empfehle aber dringend, Vergleiche bei dieser Schreibweise immer in Klammern zu setzen, man muss dies zwar nicht immer aber wenn man es immer macht, vergisst man es nicht wenn man es braucht.

Fragen stellen im Online-Excel Forum

Neu in Online-Excel: Online-Excel Newsletter

Weitere Artikel der Gruppe: Tutorials Aus Excel Standard
Nach oben