Autor: Beate Schmitz  --- Aus Excel Standard - Gruppe: Häufige Fragen

Runden - Auf-Ab und vieles mehr

Autor: Beate Schmitz - Erstellt: 2005-01      - Letzte Revision: ?
Rund ums Runden

Oft ist es sinnvoll, mit gerundeten Werten zu rechnen, da sonst der tatsächliche Zellinhalt vom sichtbaren Zellinhalt je nach Zellformatierung abweicht.

Das Runden vermeidet, dass z.B. bei der Addition von Nettowerten, die durch Division ermittelt wurden, Differenzen auftreten oder in einer Tabelle die Quersumme aus Netto und USt. nicht den Bruttobetrag ergibt.

Die jeweiligen Beispiele zeigen Ihnen, wie sich die verschiedenen Rundungsfunktionen auf ein und die gleiche Zahl auswirken:

Zum Blattanfang

kaufmännisch Runden

Die Funktion RUNDEN rundet kaufmännisch, d.h. ab 5 wird aufgerundet.
  • eine positive Zahl hinter dem Semikolon gibt die Anzahl der Dezimalstellen an
  • "0" bedeutet, runden auf die nächste ganze Zahl
  • negative Zahlen bewirken eine Rundung auf den links vom Komma stehenden Teil des Betrages
 
 ABCDEF
1      
2 kaufmännisches RundenAusgangszahlGerundet Beispiel, wie man die RUNDEN-Funktion ohne Hilfsspalte in Formeln einbindet 
3 auf x Dezimal-stellen789,24587789,253.946,25 
4 auf die nächste ganze Zahl runden789,003.945,00 
5 auf volle 100 runden800,004.000,00 
6      
Formeln der Tabelle
D3 : =RUNDEN(C3;2)
E3 : =RUNDEN(C3;2)*5
D4 : =RUNDEN(C3;0)
E4 : =RUNDEN(C3;0)*5
D5 : =RUNDEN(C3;-2)
E5 : =RUNDEN(C3;-2)*5
 


Zum Blattanfang

Auf- und Abrunden - Rundungsrichtung erzwingen

Diese Funktion bewirkt das Ausschalten der kaufmännischen Rundung, das Auf- bzw. Abrunden kann damit erzwungen werden. Die übrige Systematik ist wie bei der Funktion RUNDEN.
 
 ABCDEFG
1       
2 Auf- oder AbrundenAusgangszahlGerundet Beispiel, wie man die
AUF-/ABRUNDEN-Funktion ohne Hilfsspalte in Formeln einbindet
 
3 Aufauf x Stellen nach dem Komma:789,24378789,253.946,25 
4 auf die nächste ganze Zahl:790,003.950,00 
5 auf volle 100:800,004.000,00 
6 Abauf x Stellen nach dem Komma:789,243.946,20 
7 auf die nächste ganze Zahl:789,003.945,00 
8 auf volle 100:700,003.500,00 
9       
Formeln der Tabelle
E3 : =AUFRUNDEN(D3;2)
F3 : =AUFRUNDEN(D3;2)*5
E4 : =AUFRUNDEN(D3;0)
F4 : =AUFRUNDEN(D3;0)*5
E5 : =AUFRUNDEN(D3;-2)
F5 : =AUFRUNDEN(D3;-2)*5
E6 : =ABRUNDEN(D3;2)
F6 : =ABRUNDEN(D3;2)*5
E7 : =ABRUNDEN(D3;0)
F7 : =ABRUNDEN(D3;0)*5
E8 : =ABRUNDEN(D3;-2)
F8 : =ABRUNDEN(D3;-2)*5
 


Zum Blattanfang

Kaufmännisches Runden auf ein Vielfaches

Dies wird z.B. benötigt, wenn auf den nächsten durch 50 teilbaren Betrag gerundet werden soll.

Grundsätzlich gibt es zwei Möglichkeiten:
Entweder die RUNDEN-Funktion wird erweitert oder Einsatz der Funktion VRUNDEN.

Wird VRUNDEN eingesetzt, muss das Add-In Analyse-Funktion installiert und aktiviert sein.
 
 ABCDEFGH
1        
2 kaufmännisches Runden auf ein Vielfaches durch:AusgangszahlBeispiel-vielfachesGerundet auf das Vielfaches gem. Spalte D Beispiel, wie man die
Funktionen ohne Hilfsspalte in Formeln einbindet
Add-In Analyse-Funktion muss installiert sein: 
3 RUNDEN789,2437850800,004.000,00nein 
4 0,05789,253.946,25 
5 0,5789,003.945,00 
6 VRUNDEN50800,004.000,00ja 
7 0,05789,253.946,25 
8 0,5789,003.945,00 
9        
Formeln der Tabelle
E3 : =RUNDEN(C3/50;0)*50
F3 : =RUNDEN(C3/50;0)*50*5
E4 : =RUNDEN(C3/0,05;0)*0,05
F4 : =RUNDEN(C3/0,05;0)*0,05*5
E5 : =RUNDEN(C3/0,5;0)*0,5
F5 : =RUNDEN(C3/0,5;0)*0,5*5
E6 : =VRUNDEN(C3;50)
F6 : =VRUNDEN(C3;50)*5
E7 : =VRUNDEN(C3;0,05)
F7 : =VRUNDEN(C3;0,05)*5
E8 : =VRUNDEN(C3;0,5)
F8 : =VRUNDEN(C3;0,5)*5
 


Zum Blattanfang

Auf- und Abrunden auf ein Vielfaches - Rundungsrichtung erzwingen

Hier wird das kaufmännische Runden wieder abgeschaltet, Auf- und Abrunden wird erzwungen in Kombination mit Rundung auf ein Vielfaches:
  • das Abrunden geht mit den Funktionen ABRUNDEN oder UNTERGRENZE
  • das Aufrunden mit den Funktionen AUFRUNDEN oder OBERGRENZE
 
 ABCDEFG
1       
2 Auf- oder Abrunden auf ein Vielfaches durch:AusgangszahlBeispiel-vielfachesGerundet auf das Vielfaches gem. Spalte D Beispiel, wie man die
Funktionen ohne Hilfsspalte in Formeln einbindet
 
3 AUFRUNDEN oder OBERGRENZE789,24378508004.000 
4 8004.000 
5 ABRUNDEN oder UNTERGRENZE7503.750 
6 7503.750 
7       
Formeln der Tabelle
E3 : =AUFRUNDEN(C3/50;0)*50
F3 : =AUFRUNDEN(C3/50;0)*50*5
E4 : =OBERGRENZE(C3;50)
F4 : =OBERGRENZE(C3;50)*5
E5 : =ABRUNDEN(C3/50;0)*50
F5 : =ABRUNDEN(C3/50;0)*50*5
E6 : =UNTERGRENZE(C3;50)
F6 : =UNTERGRENZE(C3;50)*5
 


Zum Blattanfang

Das Runden von Zeiten

Ein Tag hat bei Excel den Faktor 1. Ableitend davon können Sie so für jede Zeitspanne den Bruchteil berechnen;
da ein Tag 24 Stunden hat, entspricht z.B. 1 Stunde 1/24 Tag.
Dieses Wissen ist sehr nützlich beim Runden von Zeiten.

Hier die häufigst benutzten Werte, Zwischenwerte können Sie sich nach dem Schema selbst errechnen:
 
Einheit1 sec1 min10 min15 min20 min30 min1 h
Faktor86400144014496724824
 

Diesen Faktor bauen Sie dann in die RUNDEN-Formel ein: =RUNDEN(Uhrzeitwert*Faktor;0)/Faktor

Auch bei Uhrzeiten können Sie die Funktionen Auf- und Abrunden einsetzen um die Rundungsrichtung zu erzwingen.

Hier ein Beispiel mit diesen drei Funktionen angewendet jeweils auf die gleiche Uhrzeit, damit Sie die Auswirkung vergleichen können:
 
 ABCDEFG
1       
2   Funktion: 
3   RUNDENAUFRUNDENABRUNDEN 
4 runden aufUhrzeitergibt gerundetergibt aufgerundetergibt abgerundet 
5 volle Minute17:41:3917:42:0017:42:0017:41:00 
6 10 Min.17:41:3917:40:0017:50:0017:40:00 
7 15 Min17:41:3917:45:0017:45:0017:30:00 
8 20 Min.17:41:3917:40:0018:00:0017:40:00 
9 30 Min.17:41:3917:30:0018:00:0017:30:00 
10 1 Stunde17:41:3918:00:0018:00:0017:00:00 
11       
Formeln der Tabelle
D5 : =RUNDEN($C5*1440;0)/1440
E5 : =AUFRUNDEN($C5*1440;0)/1440
F5 : =ABRUNDEN($C5*1440;0)/1440
D6 : =RUNDEN($C6*144;0)/144
E6 : =AUFRUNDEN($C6*144;0)/144
F6 : =ABRUNDEN($C6*144;0)/144
D7 : =RUNDEN($C7*96;0)/96
E7 : =AUFRUNDEN($C7*96;0)/96
F7 : =ABRUNDEN($C7*96;0)/96
D8 : =RUNDEN($C8*72;0)/72
E8 : =AUFRUNDEN($C8*72;0)/72
F8 : =ABRUNDEN($C8*72;0)/72
D9 : =RUNDEN($C9*48;0)/48
E9 : =AUFRUNDEN($C9*48;0)/48
F9 : =ABRUNDEN($C9*48;0)/48
D10 : =RUNDEN($C10*24;0)/24
E10 : =AUFRUNDEN($C10*24;0)/24
F10 : =ABRUNDEN($C10*24;0)/24
 


Fragen stellen im Online-Excel Forum

Neu in Online-Excel: Online-Excel Newsletter

Weitere Artikel der Gruppe: Häufige Fragen Aus Excel Standard
Nach oben