Autor: Peter Haserodt  --- Aus Excel Standard - Gruppe: Tutorials

Matrix Station (5) - Bald sind wir Matrixler

Autor: Peter Haserodt - Erstellt: ?      - Letzte Revision: ?Gruppenthema: 7 Folgen 1 2 3 4 5 6 7 Sie sind in Folge:5
Wahnsinn, wir sind jetzt schon so weit und haben immer noch nichts vernünftiges gemacht.
Dann fangen wir doch mal an, alle Zutaten die wir bis jetzt kennengelernt haben, zusammenzumischen.

Station 5: Wir fangen an zu matrixeln
 
 ABCDEF
1      
2 Liste GesuchtHamburg 
3 Hamburg    
4 Bremen Vorhanden:3 
5 Hamburg Vorhanden:3 
6 Bremen    
7 Hamburg    
8      
Formeln der Tabelle
E4 : {=SUMME(N(B3:B7=E2))}
E5 : {=SUMME((B3:B7=E2)*1)}

Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
 

E4 und E5 sind gleichwertig, sie dienen nur nochmals zur Erinnerung von 2 Varianten.

Wir haben Hamburg gezählt unter Verwendung einer Matrixformel. Wow.
Auch wenn Sie jetzt vielleicht sagen: Dazu gibt es doch die Funktion ZählenWenn !
Sie haben ja recht aber ob diese dann auch noch für die anderen Beispiele ausreicht?

Es geht darum, es zu verstehen. Und mit den Mitteln, die wir bis jetzt kennengelernt haben, können Sie dies wunderbar nachvollziehen. Lösen wir es doch einfach mal auf:
 
 ABCDEF
1      
2 Liste GesuchtHamburg 
3 Hamburg    
4 Bremen WAHR1 
5 Hamburg FALSCH0 
6 Bremen WAHR1 
7 Hamburg FALSCH0 
8   WAHR1 
9      
10    3 
11      
Formeln der Tabelle
D4 : {=B3:B7=E2}
E4 : =D4*1
D5 : {=B3:B7=E2}
E5 : =D5*1
D6 : {=B3:B7=E2}
E6 : =D6*1
D7 : {=B3:B7=E2}
E7 : =D7*1
D8 : {=B3:B7=E2}
E8 : =D8*1
E10 : =SUMME(E4:E8)

Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
 

Wir erzeugen eine Ergebnismatrix über einen Vergleichsoperator aus den gelben und grünen Quellmatrizen .
Dann wandeln wir dieses Ergebnis noch in Zahlen um und am Ende addieren wir das ganze.
Nur dass wir das ganze in einem Schritt gemacht haben !!!

Ein wenig mehr gefällig? Aber gerne doch!
Wir suchen Hamburg mit dem Eintrag 12
 
 ABCDEFGHI
1         
2 Liste  GesuchtHamburg12 
3 Hamburg12      
4 Bremen2  Vorhanden2  
5 Hamburg4  Vorhanden2  
6 Bremen5      
7 Hamburg12      
8         
Formeln der Tabelle
G4 : {=SUMME((B3:B7=G2)*(C3:C7=H2))}
G5 : {=SUMME((N(B3:B7=G2))*(N(C3:C7=H2)))}

Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
 

Ist das nicht bezaubernd ?

Wenn Sie dies verstanden haben, sind Sie schon weitgehend ein Matrixler !
(G4 und G5 sind wieder gleichwertig. Es soll in G4 zeigen, dass wir auf die Umwandlung in eine Zahl verzichten konnten,
da durch die Multiplikation der Wahrheitswerte automatisch Zahlen erzeugt werden.
Ich persönlich multipliziere oft mit 1 oder benutze die N() Funktion auch wenn ich diese nicht explicit benötige,
nur um es an entscheidender Stelle nicht zu vergessen. Eine Art Versicherung.

Ich denke nicht, dass ich die Formel noch erklären muss. Mit dem Wissen, welches Sie sich bis jetzt angeeignet haben,
können Sie diese problemlos alleine.

Ein berechtigter Einwand von Kennern ist sicherlich, dass man hier auch die Funktion SummenProdukt einsetzen könnte.
Ja, aber SummenProdukt ist eine Matrixfunktion, also was solls.
(Auf Summenprodukt gehe ich noch gesondert ein)

Weiter experimentieren:

Jetzt möchte ich Sie erstmal mit der ganzen Macht der Matrix-Formeln alleine lassen.
Matrixeln Sie los und gehen Sie tief hinab in die Ebenen der Logik.

Ein kleines Beispiel noch für den Zwischenstop:
 
 ABCDEFGH
1        
2      Summe in C wenn Hamburg 
3 Hamburg962688636 8035 
4 Bremen203280960   
5 Hamburg864218170 Summe in D wenn Hamburg und C kleiner 800 
6 Bremen814250931 1982 
7 Hamburg739210776   
8 Hamburg733119532 Maximum E bei Bremen 
9 Bremen146939277 960 
10 Hamburg664865172 (Hinweis: Min funktioniert so nicht,
und Max nicht korrekt bei negativen Zahlen,
da muss man dann ein wenig mehr tricksen)
 
11 Bremen442493623  
12 Hamburg684671137  
13 Hamburg927490224  
14 Bremen293639133  
15 Hamburg676117551  
16 Bremen675250724  
17 Hamburg973108973   
18 Hamburg813462798   
19        
Formeln der Tabelle
G3 : {=SUMME((B3:B18="Hamburg")*(C3:C18))}
G6 : {=SUMME((B3:B18="Hamburg")*(C3:C18<800) *(D3:D18))}
G9 : {=MAX((B3:B18="Bremen")*(E3:E18))}

Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
 



Ja und nun?

Liegt es erstmal an ihnen, sich tiefer damit zu beschäftigen.
An der nächten Station werden wir dann ein paar weitere Techniken kennenlernen.
Zur Station 6 >>
Fragen stellen im Online-Excel Forum

Neu in Online-Excel: Online-Excel Newsletter


Weitere Artikel der Gruppe: Tutorials Aus Excel Standard
Nach oben