Autor: Peter Haserodt  --- Aus Excel Standard - Gruppe: Funktionen

Text

Autor: Peter Haserodt - Erstellt: ?      - Letzte Revision: ?

Die Text Funktion - eine Zahl formatieren

Die Textfunktion ist eher eine unbekannte Funktion in der Excelwelt. Dabei lassen sich mit ihr wunderbar tatsächliche Werte einer Zelle darstellen.
Um mit dem überhaupt etwas anfangen zu können, müssen wir uns kurz mit anderen Dingen beschäftigen.
In vielen Fällen habe ich speziell formatierte Zellen, die z.B. ein Datum enthalten, eine Währung oder sonstetwas, was als Inhalt eigentlich eine Zahl hat mir aber in einem besonderen Format angezeigt wird.

Wenn Sie sich mit benutzerdefinierten Formaten nicht auskennen, empfehle ich Ihnen dringend zuerst den Artikel von Beate Schmitz zu lesen:
Benutzerdefiniertes Zellformat
Kommen Sie aber bitte dann wieder hierher zurück!

Auch empfehle ich Ihnen, sich zuerst mein Tutorial zu Datum und Uhrzeit einzuverleiben:
Datum und Zeit


Wieder da und bereit für mehr?

Hinweis:

Ich benutze hier die Formatcodes für die deutsche Ländereinstellung!


Tatsächlich lässt sich die Textfunktion ähnlich wie benutzerdefinierte Zellformate verwenden.
Einfach mal ein paar Beispiele:

 ABCD
1    
2 1515,00 € 
3    
4 0,512:00 
5 0,512:00 U12r 
6 0,512:00 Uhr 
7    
8 3950729.02.2008 
9 01.03.200801 
10 01.03.200803 
11 01.03.20082008 
12    

Formeln der Tabelle
ZelleFormel
C2=TEXT(B2;"0,00 €")
C4=TEXT(B4;"hh:mm")
C5=TEXT(B5;"hh:mm Uhr")
C6=TEXT(B6;"hh:mm U\hr")
C8=TEXT(B8;"TT.MM.JJJJ")
C9=TEXT(B9;"TT")
C10=TEXT(B10;"MM")
C11=TEXT(B11;"JJJJ")


Die Textfunktion erwartet als erstes Argument eine Zahl und als zweites Argument einen Darstellungscode.
Dieser kann gemischt sein zwischen Formatierungscodes und "echten" Zeichen.
Formatierungscodes sind Zeichen, die eine besondere Bedeutung haben.
Z.b. steht T für einen Tag und die Anzahl der T's bestimmt die Darstellung.
M steht für Monat, J für Jahr, h für Stunde, m für Minute, s für Sekunde.
Des weiteren gibt es noch Zahlenformatcodes wie : 0,00 oder #.##0,00 etc...
Diese entprechen in etwa den Codes für Zellenformate - Wie oben geschrieben hat Beate diese sehr ausführlich beschrieben.

Außer diesen Codes kann ich ganz einfach "echte" Zeichen hinzufügen.
In unserem Beispiel in der Zelle C2 sehen wir dies. Hier habe ich den Formatierungscode 0,00 angewandt und einfach noch ein Leerzeichen und ein € hinzugefügt. Dies bedeutet nichts anderes:
Wandele die Zahl in einen Text um und zwar als Zahl mit mind. einer Vorkommastelle und zwei Nachkommastellen und danach noch ein Leerzeichen und ein €.

Während die meisten anderen dargestellten Formeln und ihre Ergebnisse sich erklären dürften, fällt uns der Unterschied in den Zellen C5 und C6 doch auf.
Die Idee ist, hinter der Darstellung der Uhrzeit noch das Wort Uhr zu schreiben. Also denkt man sich flott und geschwind:
hh:mm und Uhr und fertig ist das Kind.
Aber wie man sieht, kommt da etwas Unschönes dabei raus. Nämlich anstatt Uhr habe ich auf einmal U12r stehen.
Zu erklären ist dies leicht. h steht ja für Stunde und so wird aus meinem Uhr ganz einfach U dann die Stunde und ein r.

Maskieren:

Ein bei den meisten unbekannter "Trick" ist: Möchte ich ein Zeichen, welches eigentlich ein Formatcode ist, darstellen, muss ich es maskieren. Dies geschieht, indem ich einen Backslash \ davor schreibe.

Dies ist nicht so einfach, da einen auch unerwartete Zeichencodes überraschen können.

 BC
505.03.2008Der Monat ist: März

Formeln der Tabelle
ZelleFormel
C5=TEXT(B5;"D\er \Mo\na\t i\s\t: MMMM")


Wie wir hier sehen, ist das schon richtig komplex, die ganzen Maskierereien.
Wer sichergehen will, kann einfach jedes Zeichen, bzw. jedes alphanumerische Zeichen maskieren:
=TEXT(B5;"\D\e\r \M\o\n\a\t \i\s\t: MMMM")

Um einen Backslash auszugeben, muss ich ihn mit sich selbst maskieren also: \\

Wem dies alles zuviel ist, kann natürlich einfach mit einer Verknüpfung arbeiten, etwa:
="Der Monat ist: " & TEXT(B5;"MMMM")

Wichtig:

Mit dem Ergebnis der Textfunktion können Sie - in der Regel - nicht mehr weiterrechnen!
Ihre Meinung zu Online Excel Geben Sie uns ein Feedback
Ein Ärgernis:

Auch hier ist mal wieder die Excel Hilfe schlampig übersetzt worden.
In vielen Excelversionen werden falsche Formatierungscodes für die deutsche Ländereinstellung dargestellt.

In Excel 2003 findet man in der Hilfe z.B. folgendes:
Tage als 1-31 d

oder:
Jahre als 1900-9999 yyyy


Hier wurden die englischen Codes benutzt d anstatt T und y anstatt J.
Ich verweise also nochmals auf Beates Artikel zu den Zellformaten, denn dort hat sie viele Formatcodes beschrieben.

Weitere Artikel der Gruppe: Funktionen Aus Excel Standard
Nach oben
ToDo
Google Werbung