Autor: Peter Haserodt  --- Aus Excel Standard - Gruppe: Funktionen

Häufigkeit

Autor: Peter Haserodt - Erstellt: ?      - Letzte Revision: ?

Häufigkeit

Nehmen Sie sich ein Beruhigungsgetränk Ihrer Wahl (Pfefferminztee, Kamillentee, Kalter Hopfentee) und sparen Sie nicht an der Menge. Sie werden es häufig brauchen.

Ach Quatsch, Häufigkeit ist viel einfacher als man glaubt, wenn man es einmal nachvollzogen hat.
Wie so oft, schüchtern einen eher die Argumentnamen ein. Trotzdem sollten Sie etwas Matrixerfahren sein, zumindest für den unteren Teil, in welchem ich Ihnen etwas Zauberei mit Häufigkeit aufzeigen will.

Und bevor wir uns and die eigentliche Funktion wagen, wollen wir einfach mal den Sinn uns erarbeiten.
(Arbeit - dieses Wort klingt auch schon wieder zum weglaufen, bleiben Sie trotzdem bei mir)

Stellen Sie bitte folgendes her, bitte genau so, wie ich es nun aufzeige, auch den grünen Bereich, beachten Sie, dass dieser eine Zelle mehr hat!

 ABCD
1    
2 DatenKlassenAuswertung
3 510 
4 1120 
5 1230 
6 1140 
7 55  
8 33  
9 34  
10 33  
11 36  
12 10  

Nun gut, dies war noch einfach.
Stören Sie sich nicht an den Namen Daten und Klassen, sind auch nur Begriffe und wir sehen gleich ihre eigentliche Bedeutung:
Ich benutze sie hier, weil die Funktion Häufigkeit folgenden Konstrukt hat:
HÄUFIGKEIT(Daten;Klassen)


Daten sind nichts anderes als Zahlen, die Sie irgendwo einordnen wollen, und Klassen sind die Bereiche.
Stellen Sie sich einfach mal vor, die Daten wären Eurobeträge (Einkäufe) und Sie wollen wissen, wieviele in welche Bereiche passen. Also wie oft sind Sie aus dem Supermarkt gekommen und haben zwischen 30 und 40 Euro etc... ausgegeben.
Häufigkeit ordnet Zahlenwerte einfach in vorgegebene Bereiche(Klassen) ein.
Schauen wir mal: Die Zahlen 33,33,34,36 würden dem obigen genügen, also 4 Einkäufe.

Sie sehen auch die Zahl 5, die irgendwie nirgends reinpasst und auch die Zahl 55 mag man nicht so richtig.
Aber Geduld, jetzt legen wir los!

Los Los - die Häufigkeit wartet!

Bitte seien Sie nun sehr sorgfälgit (so wie immer)!
Markieren Sie nun den grünen Bereich (D3 bis D7) und geben Sie folgendes ein:
(Achtung Achtung! Nach der Eingabe dürfen Sie nicht normal abschließen, sondern Sie müssen die Formeleingabe mit STRG+Umschalt+Eingabetaste abschließen, Häufigkeit muss als Matrixforme eingegeben werden)l!!!

=HÄUFIGKEIT(B3:B12;C3:C6)


und mit STRG+ Umschalttaste + Eingabetaste abschließen.
Durch das Markieren aller Zellen, wird die Formel nun in alle eingetragen und es werden von Excel geschweifte Klammern hinzugefügt (Wie es sich für eine Matrix gehört) .

Das Ergebnis sollte nun so aussehen:

 ABCD
1    
2 DatenKlassenAuswertung
3 5102
4 11203
5 12300
6 11404
7 55 1
8 33  
9 34  
10 33  
11 36  
12 10  

Formeln der Tabelle
ZelleFormel
D3{=HÄUFIGKEIT(B3:B12;C3:C6)}
D4{=HÄUFIGKEIT(B3:B12;C3:C6)}
D5{=HÄUFIGKEIT(B3:B12;C3:C6)}
D6{=HÄUFIGKEIT(B3:B12;C3:C6)}
D7{=HÄUFIGKEIT(B3:B12;C3:C6)}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Ganz ruhig, Sie werden gleich alles verstehen und ein AHA Erlebnis wartet auf Sie.
Wie gesagt, Häufigkeit ordnet Zahlen in Bereiche ein und zwar wie folgt:
Zuerst sucht sie den kleinsten Wert in Klassen - in unserem Fall ist es der Wert 10.
Dann sucht sie in Daten alle Zahlen, die Kleiner Gleich dieses Wertes sind, in unserem Fall also alle Zahlen die kleiner 10 oder gleich 10 sind.
Wir haben hier also die 5 und die 10, die da hinein fallen. Dies sind 2 Stück also kommt neben die 10 die Zahl 2.

Jetzt sucht sich Häufigkeit die Zweitkleinste Zahl in Klassen - in unserem Fall die 20 und sucht alle Zahlen in Daten, die Kleiner Gleich dieser Zahl sind und Größer als die nächstskleiner Zahl in Klassen.
In unserem Fall also alle Zahlen die Kleiner Gleich 20 und Größer als 10 sind!
Dies trifft bei uns für: 11,12,11 zu. (Die 11 kommt zwei mal vor, wird also auch 2 mal gezählt!)
Dies ergibt - wenn wir es selber zählen - z.B. indem wir einen Kerbe in den Bildschirm ritzen - ne ne, bloß nicht - 3.
Und siehe da, neben der 20 steht eine 3!

So geht es nun weiter.
Als nächstes kommt bei uns die 30 und die nächstkleinere Zahl ist die 20. In Daten haben wir keine Zahlen, die da hinein passen, also 0.
Jetzt das gleiche mit 40 und 30 und da finden wir 4.

Und nun kommt der Sonderfall!
Sicherlich waren Sie schon verwundert, warum wir eine Zelle mehr markiert hatten, als wir Klassen haben.
Dies liegt daran, dass Häufigkeit noch einen weiteren Wert ausgibt, nämlich als letzten Wert die Anzahl von Zahlen in Daten, die größer als der letzte Klassenwert sind.
Dies ist bei uns die 55.

Zu merken:

Die Funktion Häufigkeit gibt immer einen Wert mehr aus, als Zahlen in Klassen vorhanden sind.

Eigentlich war es das schon. Verblüffend wie einfach Häufigkeit doch ist!
Aber man kann Häufigkeit auch noch "missbrauchen", deswegen mache ich noch nicht Schluss.
Aber erstmal:
 Peter Haserodt
  • Formelhilfe
  • Makroentwicklung
  • VBA-Programmierung
  • + + + + + + + + +
Zwischenbemerkung 1

Selbtstverständlich können Sie Häufigkeit als ganz normale Matrixfunktion verwenden und weiterbearbeiten.
Sie müssen nicht über den Weg der Zellen gehen. Weiter unten wird dazu noch ein Beispiel folgen.
Aber für die Matrixerfahrenen, einfach mal ausprobieren, nur in eine Zelle zu schreiben und dann mit F9 auflösen!

Zwischenbemerkung 2

Die Zahlen in Klassen müssen nicht sortiert sein.
Dies können Sie selbst ausprobieren.

Aber selbstverständlich ist es für die Übersicht absolut besser (und sicherlich auch für die Weiterverarbeitung)

Zwischenbemerkung 3

Doppelte Zahlen in Klassen - was passiert?
Normalerweise gibt dies keinen Sinn, in Klassen doppelte Zahlen zu haben.
Aber wie behandelt Häufigkeit dies? Nun ganz einfach, die zweite Zahl erhält eine 0.
Unser Beispiel leicht abgewandelt:

 BCD
35102
411203
512200
611404
755 1
833  
934  
1033  
1136  
1210  

Wie Sie sehen, hat die erste 20 die 3 und die zweite 20 eine 0.
Wunderbar! Aber was nützt uns diese Information???

Dies werde ich Ihnen gleich an ein paar "Spielereien" vorführen.
Zuvor sollten Sie sich aber erstmal mit ein paar eigenen Experimenten mit der Häufigkeit näher vertraut machen.

Wagemutiges Experiment 1 (Ab hier sollten Sie mit Matrix wirklich vertraut sein)

Was Sie nun erwartet, hat mit dem eigentlichen Sinn von Häufigkeit rein gar nichts zu tun.
Aber es macht Spass und man kann es gebrauchen.

Eine interessante Variante ist nämlich, die Daten auf sich selbst als Klasse abzubilden.
Schauen wir uns dies erstmal in einem kleinen Beispiel an:

 ABC
1   
2 12
3 2 
4 1 
5 3 
6 12 
7 2 
8 3 

Formeln der Tabelle
ZelleFormel
C2{=HÄUFIGKEIT(B2:B8;B2:B8)}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Das wir jetzt in der Zelle C2 eine 2 stehen haben, liegt einfach daran, dass wir den ersten Indexwert der Rückgabematrix erhalten, also nichts anderes als dass die Klasse 1 zweimal vorkommt.
Wenn Sie die Formel in der Bearbeitungsleise auflösen, steht folgendes da:
={2;2;0;2;1;0;0;0}

Dies wollen wir genauer analysieren:
Unsere erste Klasse ist 1, da wir ja die Klasse gleich der Daten haben.
Es gibt 2 Werte - nämlich 2 Einsen in unseren Daten.
Jetzt das ganze für die 2. Danach wieder die 1, die wurde aber schon abgehandelt von Häufigkeit also eine 0.
(Sie obige Zwischenbemerkung)
Und so weiter.
Wir bekommen also für jede Zahl unserer Daten genau zurück, wie oft diese vorkommt.
Tatsächlich interessiert dies uns aber überhaupt nicht, viel interessanter ist es, wieviele Teile meiner Ergebnismatrix größer als 0 sind. Denn damit kann ich wirklich etwas anfangen, nämlich die Anzahl der verschiedenen Zahlen ermitteln. Und siehe da, es sind genau 4 Stück.
Und dies können wir nun mit einer Formel auswerten:

 ABC
1   
2 14
3 2 
4 1 
5 3 
6 12 
7 2 
8 3 

Formeln der Tabelle
ZelleFormel
C2=SUMMENPRODUKT(--(HÄUFIGKEIT(B2:B8;B2:B8)>0))


Man beachte, dass wir die Formel nicht als Matrixformel eingeben müssen, da Summenprodukt eine Matrixfunktion ist.

Sicherlich lässt sich dies auch noch anders auswerten, dies überlasse ich nun aber Ihnen, damit rumzuspielen.
(P.S. das -- dient nur dazu, den boolschen Rückgabewert in 0/1 umzuwandeln, man könnte anstatt -- auch N (die Funktion N) benutzen)

Natürlich kann man dies auch noch anders erreichen aber ich möchte Sie ja auf die Möglichkeiten von Häufigkeit aufmerksam machen und hoffe, dass Sie dies für sich selbst ein wenig analysieren.

Aber ein Beispiel habe ich noch!

Wagemutiges Experiment 2

 ABCD
1    
2 111,5
3 1  
4 1,5  
5 2  
6 2  
7 3  

Formeln der Tabelle
ZelleFormel
C2=KKLEINSTE(B2:B7;2)
D2=KKLEINSTE(WENN(HÄUFIGKEIT(B2:B7;B2:B7)>0;B2:B7;"");2)


Ich denke Sie sehen sofort den Unterschied!
Setzte ich KKleinste ein, dann erhalte ich als Zweitniedrigsten Wert die 1.
Manchmal interessiert mich aber der Zweitniedrigste Wert der eindeutigen Zahlen und schon haben wir unsere Häufigkeit im Gepäck.
Wir ersetzen einfach alle Werte unserer Häufigkeit die nicht 0 sind durch den Datenwert und die anderen durch "".
Dann können wir wunderbar Funktionen darauf ansetzen, die Leere Werte ignorieren.
Schön - oder?
Hinweis: Diese Berechnungsweise setzt voraus, dass keine Leerzellen vorhanden sind!
(Leerzellen werden hier als 0 interpretiert)


Dies nun genauer zu analysieren überlasse ich jetzt wirklich Ihnen!
So häufig wie ich heute Häufigkeit geschrieben habe!

Fragen stellen im Online-Excel Forum

Neu in Online-Excel: Online-Excel Newsletter

Weitere Artikel der Gruppe: Funktionen Aus Excel Standard
Nach oben